#! /bin/csh -f
########################################################################
#                 copyright 2001, Amoco Production Company             #
#                             All Rights Reserved                      #
#                     an affiliate of BP America Inc.                  #
########################################################################
#
# This script is a part of FreeUSP - the UNIX Seismic Processing system.
#
if ( $#argv < 1 ) then
	echo " "
	echo " upsummer: generate a High Frequency Determination Panel"
	echo " "
	echo " Input:"
	echo " "
	echo " -N               Input Data Filename"
	echo " -rs              Start Record"
	echo " -re              End Record"
	echo " -fmin            Starting f1 Frequency (default=0)"
	echo " -fmax            Ending f4 Frequency (default=95Hz)"
	echo " -finc            Frequency Increment (def=10Hz)"
	echo " -df              Separation between corner frequencies (def=5)"
	echo " "
	echo " Usage:"
	echo " "
	echo " upsummer -N[] -rs[] -re[] -fmin[] -fmax[] -finc[] -df[]"
	exit
endif
set NM = `usparg -N " " $*`

if ( -e $NM ) then
else	
	echo $NM"  input file does not exist:"
        echo "rerun with correct file name"
        exit
endif
	
@ RS = `usparg -rs 1 $*`
@ RE = `usparg -re 0 $*`
@ F1 = `usparg -fmin 0 $*`
@ FMAX = `usparg -fmax 95 $*`
@ FINC = `usparg -finc 10 $*`
@ DF   = `usparg -df 5 $*`

# Initialize filter corner frequencies

@ F2 = $F1 + $DF
@ F3 = $F1 + $DF + $DF
@ F4 = $F1 + $DF + $DF + $DF

# Constant Bandpass Upsum Construction

@ F1in = $F1
@ F2in = $F2
@ F3in = $F3
@ F4in = $F4

while ( $F4in <= $FMAX  )

  echo "Bandpass:  F1= "$F1in"  F2= "$F2in"  F3= "$F3in"  F4= "$F4in
  editt -N$NM -rs$RS -re$RE |\
  sctvf -R -db60 -f1$F1in -f2$F2in -f3$F3in -f4$F4in |\
  davc |\
  editt -t$F4in -U -O$NM$F3in$F4in

  @ F1in += $FINC
  @ F2in += $FINC
  @ F3in += $FINC
  @ F4in += $FINC

end

# Constant Bandpass Filters

@ F1in = $F1
@ F2in = $F2
@ F3in = $F3
@ F4in = $F4

while ( $F4in <= $FMAX  )

  apend -N$NM$F3in$F4in -OBandPass$NM

  @ F1in += $FINC
  @ F2in += $FINC
  @ F3in += $FINC
  @ F4in += $FINC

end


# Constant Bandpass Upsum Construction 

@ F1in = $F1
@ F2in = $F2
@ F3in = $F3
@ F4in = $F4
@ count = 1

cp $NM$F3$F4 BandPassUpsum$NM

while ( $F4in < $FMAX  )
  @ F1in += $FINC
  @ F2in += $FINC
  @ F3in += $FINC
  @ F4in += $FINC

 editt -NBandPassUpsum$NM -rs$count -re$count |\
 vstak -N2$NM$F3in$F4in |\
 editt -t$F4in -U |\
 apend -OBandPassUpsum$NM

  @ count += 1

end

# make panel and run record constant median gasp
# put raw record at front of panel

davc -N$NM -rs$RS -re$RE -OUpsumPanel$NM

# number filter records with highest frequency

apend -NBandPass$NM -OUpsumPanel$NM

# number filter records with highest frequency

apend -NBandPassUpsum$NM -OUpsumPanel$NM

# put a few dead traces between records for plotting

embed -NUpsumPanel$NM -L3 |\
gasp -OUpsumPanelGasp$NM -rec -med
mv UpsumPanelGasp$NM  UpsumPanel$NM 

# delete all un-needed datasets

rmprint
\rm BandPassUpsum$NM
\rm BandPass$NM
\rm GaspCoef

@ F1in = $F1
@ F2in = $F2
@ F3in = $F3
@ F4in = $F4

while ( $F4in <= $FMAX  )

  \rm $NM$F3in$F4in 

  @ F1in += $FINC
  @ F2in += $FINC
  @ F3in += $FINC
  @ F4in += $FINC

end
