#! /bin/csh -f
########################################################################
#                 copyright 2001, Amoco Production Company             #
#                             All Rights Reserved                      #
#                     an affiliate of BP America Inc.                  #
########################################################################
#
# This script is a part of FreeUSP - the UNIX Seismic Processing system.
#
# give command line help if requested
if ( $#argv < 1 ) then
	echo " "
	echo " downsum: generate a Low Frequency Determination Panel"
	echo " "
	echo " Input:"
	echo " "
	echo " -N                   Input Data Filename"
	echo " -rs                  Start Record"
	echo " -re                  End Record"
	echo " -f1                  Starting f1 Frequency"
	echo " -fmax                Ending f4 Frequency"
	echo " "
	echo " Usage:"
	echo " "
	echo " downsum -N -rs -re -f1 -fmax"
	exit
endif

# parse command line paramters
set NM = `usparg -N " " $*`

if ( -e $NM ) then
else	
	echo $NM"  input file does not exist:"
        echo "rerun with correct file name"
        exit
endif

@ RS = `usparg -rs 1 $*`
@ RE = `usparg -re 0 $*`
@ F1 = `usparg -f1 0 $*`
@ FMAX = `usparg -fmax 95 $*`

# Initialize filter corner frequencies
@ F2 = $F1 + 5
@ F3 = $F1 + 10
@ F4 = $F1 + 15

# Downsum Bandpass Construction
@ F1in = $F1
@ F2in = $F2
@ F3in = $F3
@ F4in = $F4

while ( $F4in <= $FMAX  )

  editt -N$NM  -rs$RS -re$RE |\
  sctvf -R -db60 -f1$F1in -f2$F2in -f3$F3in -f4$F4in |\
  davc -M |\
  editt -t$F4in -U -O$NM$F3in$F4in

  @ F1in += 10
  @ F2in += 10
  @ F3in += 10
  @ F4in += 10

end

# Constant Bandpass Filters

@ F1in -= 10
@ F2in -= 10
@ F3in -= 10
@ F4in -= 10

while ( $F1in >= $F1  )

  apend -N$NM$F3in$F4in -OBandPass$NM

  @ F1in -= 10
  @ F2in -= 10
  @ F3in -= 10
  @ F4in -= 10

end


# Constant Bandpass Downsum Construction 
@ F1in = $FMAX - 15
@ F2in = $FMAX - 10
@ F3in = $FMAX - 5
@ F4in = $FMAX
@ count = 1

cp $NM$F3in$F4in BandPassDownsum$NM

@ F1in -= 10
@ F2in -= 10
@ F3in -= 10
@ F4in -= 10

while ( $F1in >= $F1 )

 editt -NBandPassDownsum$NM -rs$count -re$count |\
 vstak -N2$NM$F3in$F4in  |\
 editt -t$F4in -U |\
 apend -OBandPassDownsum$NM

  @ count += 1
  @ F1in -= 10
  @ F2in -= 10
  @ F3in -= 10
  @ F4in -= 10

end

# make panel and run record constant median gasp
# put raw record at front of panel

davc -N$NM -M -rs$RS -re$RE -ODownsumPanel$NM

# number filter records with highest frequency

apend -NBandPass$NM -ODownsumPanel$NM

# number filter records with highest frequency

apend -NBandPassDownsum$NM -ODownsumPanel$NM

# put a few dead traces between records for plotting

embed -NDownsumPanel$NM -L3 |\
gasp -ODownsumPanelGasp$NM -rec -med
mv DownsumPanelGasp$NM  DownsumPanel$NM 

# delete all un-needed datasets

rmprint
\rm BandPassDownsum$NM
\rm BandPass$NM
\rm GaspCoef

@ F1in = $F1
@ F2in = $F2
@ F3in = $F3
@ F4in = $F4

while ( $F4in <= $FMAX  )

  \rm $NM$F3in$F4in 

  @ F1in += 10
  @ F2in += 10
  @ F3in += 10
  @ F4in += 10

end
